@echo off
setlocal EnableExtensions

set "SCRIPT_DIR=%~dp0"
set "ROOT_DIR=%SCRIPT_DIR%.."
set "PORT=3000"
set "HOST=127.0.0.1"
set "BASEURL=http://%HOST%:%PORT%"
set "START_PAGE=%BASEURL%/Dates/"

cd /d "%ROOT_DIR%"

echo.
echo ==========================================
echo   DATES DISPOS - Lancement local
echo ==========================================
echo Dossier projet : %CD%
echo URL cible      : %START_PAGE%
echo.

where node >nul 2>nul
if errorlevel 1 (
  echo [ERREUR] Node.js est introuvable dans le PATH.
  echo [INFO]   Installe Node.js ou lance la giga app manuellement avec npm start.
  echo.
  pause
  exit /b 1
)

powershell -NoProfile -ExecutionPolicy Bypass -Command "if (Get-NetTCPConnection -LocalPort %PORT% -ErrorAction SilentlyContinue) { exit 0 } else { exit 1 }"
if not errorlevel 1 (
  echo [OK] Un serveur ecoute deja sur %BASEURL%.
  echo [OK] Ouverture de Dates Dispos...
  start "" "%START_PAGE%"
  exit /b 0
)

echo [OK] Demarrage du serveur Animation sur %BASEURL%
echo.

start "Animation App Server" cmd /k "node server.mjs"

timeout /t 1 /nobreak >nul

echo [OK] Ouverture de Dates Dispos dans le navigateur...
start "" "%START_PAGE%"

echo.
echo Serveur lance. Fermer la fenetre "Animation App Server" pour l'arreter.
echo.
exit /b 0